mirror of
https://github.com/ntop/ntopng.git
synced 2026-05-02 17:00:10 +00:00
151a047760
* First sketch of fuzzing * Add m4 script The script is used in the fuzzing build * Add stub sources in the makefile * [Fuzz] Add RedisStub * Add gitignore for fuzz dir * Remove definition of non-implemented method * [Fuzz] Refactoring code * [Fuzz] Separate the protobuf support in the makefile * Clean fuzzing related object files * [Fuzz] Fix makefile * Change gitignore * [Fuzz] Separate headers * [Fuzz] Add README.md * [Fuzz] Change make target * [Fuzz] Update README.md * Add compatibilty with autoconf < 2.71 * Optionally disable hiredis integration * Include hiredis only for production build * [Fuzz] Disable period activities * Remove unused dependencies for librrd * Optionally use static linking for zmq library * Add debug output regarding the linking of libzmq * [Fuzz] Do not run on empty input * Optionally use static linking for libjson-c * Optionally use static linking for libmaxminddb * Make mysqlclient dependency as optional * Change gitignore * [Fuzz] Add corpus for fuzz_dissect_packet * [Fuzz] Refactor fuzz_dissect_packet * Change gitignore * [Fuzz] Use correct naming for corpus * [Fuzz] Add dictionary * [Fuzz] Fix declaration of LLVMFuzzerInitialize * [Fuzz] Refactor onefile * [Fuzz] Fix the initialization memory leaks * [Fuzz] Fix invocation of LLVMFuzzerInitialize * Remove double githooks folder * [Fuzz] Set interface pcap_data_link * Change gitignore * Use pkg-config for detecting protobuf libraries * Add license * Improve error message
54 lines
2.1 KiB
Text
54 lines
2.1 KiB
Text
# ===========================================================================
|
|
# https://www.gnu.org/software/autoconf-archive/ax_check_compile_flag.html
|
|
# ===========================================================================
|
|
#
|
|
# SYNOPSIS
|
|
#
|
|
# AX_CHECK_COMPILE_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
|
|
#
|
|
# DESCRIPTION
|
|
#
|
|
# Check whether the given FLAG works with the current language's compiler
|
|
# or gives an error. (Warnings, however, are ignored)
|
|
#
|
|
# ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
|
|
# success/failure.
|
|
#
|
|
# If EXTRA-FLAGS is defined, it is added to the current language's default
|
|
# flags (e.g. CFLAGS) when the check is done. The check is thus made with
|
|
# the flags: "CFLAGS EXTRA-FLAGS FLAG". This can for example be used to
|
|
# force the compiler to issue an error when a bad flag is given.
|
|
#
|
|
# INPUT gives an alternative input source to AC_COMPILE_IFELSE.
|
|
#
|
|
# NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
|
|
# macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
|
|
#
|
|
# LICENSE
|
|
#
|
|
# Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
|
|
# Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
|
|
#
|
|
# Copying and distribution of this file, with or without modification, are
|
|
# permitted in any medium without royalty provided the copyright notice
|
|
# and this notice are preserved. This file is offered as-is, without any
|
|
# warranty.
|
|
|
|
#serial 6
|
|
|
|
AC_DEFUN([AX_CHECK_COMPILE_FLAG],
|
|
[AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
|
|
AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]flags_$4_$1])dnl
|
|
AC_CACHE_CHECK([whether _AC_LANG compiler accepts $1], CACHEVAR, [
|
|
ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
|
|
_AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1"
|
|
AC_COMPILE_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
|
|
[AS_VAR_SET(CACHEVAR,[yes])],
|
|
[AS_VAR_SET(CACHEVAR,[no])])
|
|
_AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
|
|
AS_VAR_IF(CACHEVAR,yes,
|
|
[m4_default([$2], :)],
|
|
[m4_default([$3], :)])
|
|
AS_VAR_POPDEF([CACHEVAR])dnl
|
|
])dnl AX_CHECK_COMPILE_FLAGS
|
|
|